Caranya dengan memproteksi sheet terkait. Misalkan untuk sheet Lat-1, pastikan range G18:I29 dalam keadaan Locked, sedangkan range E18:F29 tidak (agar bisa diedit). Gambarannya:

Atau bisa tanya om Google cara memproteksi sel Excel... ;)

Sama-sama mas @m.nur ... :) Gambar tersebut merupakan GIF Animation, saya capture menggunakan aplikasi gratis Screen To Gif .

[1] Beberapa formula yang dapat digunakan untuk sheet LAT-6 (kolom G — Harus Kembali):

=F7+((RIGHT(D7)="A")+2)
=F7+((RIGHT(D7;4)="LAMA")+2)
=IF(RIGHT(D7;4)="BARU";F7+2;F7+3)
=F7+(ISERROR(SEARCH("BARU";D7))*1+2)

Untuk kolom I — Lewat Batas (Hari):

=H7-G7

[2] Beberapa formula yang dapat digunakan untuk sheet LAT-7 (kolom E — Tarif/hari (Rp)):

=INDEX($C$19:$D$21;FIND(MID(B6;2;1);"KXU");RIGHT(B6;1)*1)
=INDEX($C$19:$D$21;MATCH(LEFT(B6;3);$B$19:$B$21;0);RIGHT(B6;1)*1)
=INDEX($C$19:$D$21;MATCH(MID(B6;2;1);{"K";"X";"U"};0);RIGHT(B6;1)*1)
=INDIRECT(CHOOSE(RIGHT(B6);"C";"D")&MOD(9-(FIND(LEFT(B6;3);$B$19&$B$20&$B$21)-1);4)+ROW($B$18))
=LOOKUP(LEFT(B6;3);$B$19:$B$21;IF(RIGHT(B6)*1=1;$C$19:$C$21;$D$19:$D$21))
=LOOKUP(LEFT(B6;3);$B$19:$B$21;CHOOSE(MATCH(RIGHT(B6)*1;{1;2});$C$19:$C$21;$D$19:$D$21))
=OFFSET($B$18;MATCH(LEFT(B6;3);$B$19:$B$21);RIGHT(B6)*1)
=VLOOKUP(LEFT(B6;3);$B$19:$D$21;CHOOSE(RIGHT(B6;1);2;3);0)
=VLOOKUP(LEFT(B6;3);$B$19:$D$21;IF(RIGHT(B6;1)*1=1;2;3);0)
=VLOOKUP(LEFT(B6;3);$B$19:$D$21;MATCH(RIGHT(B6)*1;{1;2})+1;0)
=VLOOKUP(LEFT(B6;3);$B$19:$D$21;RIGHT(B6;1)*1+1;0)

Silahkan berkreasi dengan formula-formula lain yang bisa digunakan... ;)

Pada formula:

... RIGHT(B6;1)*1+1 ...

fungsi RIGHT(B6;1) akan menghasilkan nilai 1 atau 2. Karena fungsi RIGHT(B6;1) pada dasarnya menghasilkan tipe nilai berupa teks, maka kita tambahkan notasi *1 (meski sebenarnya hal ini tidak diperlukan karena sudah ada notasi +1 yang akan mengubah tipe nilainya menjadi numerik).

Oleh karena tabel yang dirujuk berada pada range B19:D21, artinya range B19:B21 (kolom ke-1) merupakan area pencarian nilai, dan range C19:D21 (kolom ke-2 dan kolom ke-3) sebagai area pengembalian nilai. Karena fungsi RIGHT(B6;1) hanya akan menghasilkan nilai 1 atau 2, maka tanpa notasi +1 kolom yang digunakan sebagai area pengembalian nilai adalah kolom ke-1 (kolom B) atau kolom ke-2 (kolom C). Agar fungsi VLOOKUP dapat mengambil hasilnya dari kolom yang tepat, yakni kolom ke-2 (kolom C) atau kolom ke-3 (kolom D), maka ditambahkan notasi +1 terhadap hasil dari fungsi RIGHT(B6;1) tersebut.

Demikian...

Jika pada sebuah sel sudah terisi dengan formula, mengisi sel tersebut dengan sebuah nilai akan menghapus formula pad sel tersebut. Kecuali diotomasi dengan VBA Code. Kalau seperti yang mas @m.nur inginkan, hanya bisa dilakukan dengan menggunakan fungsi SUM dimana nilai diinput secara langsung:

=SUM(5;8;3)

Demikian...

@Irfan_pals Apa ada file beserta kunci jawabannya??

Gak ada mas... :D Diskusikan saja jika ada kendala, jadi bisa sama-sama belajar... ;)

Pagi juga mas @m.nur ...

... utk masukin formula diatas harus ada datanya dulu ya...

Ya... karena jika tidak ada datanya, fungsi COUNTIF($A$2:$A$8;$A$2:$A$8) akan menghasilkan nilai 0 (nol), dan jika digabungkan dengan notasi 1/n akan menghasilkan kesalahan #DIV/0! Gunakan fungsi IFERROR untuk menghilangkan tampilan kesalahan tersebut:

=IFERROR(SUMPRODUCT(1/COUNTIF($A$26:$A$47;$A$26:$A$47));0)

...kenapa harus pke absolute (f4) ya...

Tidak mutlak harus menggunakan alamat absolut jika formulanya hanya digunakan pada satu sel saja. Namun jika formula yang sama disalin ke sel lainnya, Excel otomatis akan menyesuaikan alamat sel atau range yang dijadikan rujukan secara relatif terhadap posisi awal formula. Bila alamat sel atau range yang diacu sifatnya statis, menggunakan alamat absolut akan membuat alamat sel atau range yang diacu menjadi tetap sehingga meskipun formulanya disalin, rujukannya tetap sama.

Bila ingin range rujukan bersifat dinamis, mas @m.nur bisa mencoba menggunakan teknik Dynamic Named Range, biasanya menggunakan fungsi OFFSET. Contohnya lihat pada file terlampir... ;)

@m.nur ... File yang saya lampirkan pada dasarnya hanya membahas tentang Dynamic Named Range. Kalau yang mas @m.nur maksud adalah formula pada sel D3, gunakan saja formula berikut:

=SUMPRODUCT(($A$25:$A$69<>"")/COUNTIF($A$25:$A$69;$A$25:$A$69&""))

Demikian... ;)

Halo @Fathur Rohman ... Kalau nilai pada kolom G dan kolom H bertipe DATE (atau numerik), pada dasarnya Anda bisa melakukan kalkulasi pengurangan terhadap nilai dari kedua kolom. Bila gagal, maka periksa kembali tipe nilai pada kedua kolom. Lakukan konversi terhadap tipe kedua kolom.

Mungkin itu masalahnya. Untuk lebih pastinya, sebaiknya buat diskusi baru dan lampirkan filenya. Mudah-mudahan bisa dibantu oleh rekan-rekan di sini.

Demikian.