@awe

mungkin karena halaman yang dimaksud tidak termuat secara utuh di InternetExplore, saya coba ambil harga di situs lain baik-baik aja,

Sub GetFromWeb()
Dim IE As New InternetExplorer
Dim htmlDoc As HTMLDocument
Dim Harga As String

IE.Visible = False
IE.navigate "https://www.tokopedia.com/jorkaefgame/tombol-reset-super-slim?src=topads"
Do
    DoEvents
Loop Until IE.readyState = READYSTATE_COMPLETE
Set htmlDoc = IE.document
Harga = htmlDoc.getElementsByClassName("rvm-price mr-15")(0).innerText
MsgBox Harga
IE.Quit
End Sub

sementara kalau ambil konten lain dari situs pada file (misalnya nama barang) bisa

Sub GetFromWeb()
Dim IE As New InternetExplorer
Dim htmlDoc As HTMLDocument
Dim NamaBarang As String

IE.Visible = False
IE.navigate "https://www.jakmall.com/abc-store/sol-sepatu-memory-foam-1-pasang#7012901751858"
Do
    DoEvents
Loop Until IE.readyState = READYSTATE_COMPLETE
Set htmlDoc = IE.document
NamaBarang = htmlDoc.getElementsByClassName("dp__name")(0).innerText
MsgBox NamaBarang
IE.Quit
End Sub

kalau ada alternatif solusi dari teman2 lain, silahkan dibantu

@awe Saya memcoba untuk mengambil harga dengan script yang bpak berikan di atas tetapi tidak bisa, apakah saya ada miss sesuatu atau get elementnya salah untuk mengambil harga barang dari website tersebut?

seperti yang saya sampaikan diatas, bahwa kemungkinannya adalah karena halaman yang dimaksud tidak termuat secara utuh di InternetExplore. berikut tampilannya :

sedangkan kalau menggunakan browser lain, tampilannya :

jadi halaman tersebut jika di buka dengan Internet Explore, class "dp__price dp__price--2" tidak ditemukan. demikian asumsi dari saya.

semoga ada teman-teman lain yang punya solusinya, misalnya ambil data dari chrome

@awe ... Ketika saya melalukan action script itu, saya mendapat error box yang mengarah ke barisan harga barang. Saya sudah pastikan bahwa tahap pengambilan script sudah benar, tetapi masih belum ketemu juga kenapa bisa muncul error box tersebut ...

Script yang mas @Awe buat sebenarnya tidak ada masalah, jika elemen HTML yang mau diambil memang ada pada objek HTMLDocument. Script berikut ini:

...
Set hargaawal = html.getElementsByClassName("dp__price dp__price--2")(0)
...

gagal dikarenakan elemen yang dimaksud memang tidak ada pada objek objek HTMLDocument, meski status dokumen sudah lengkap (Document Complete). Mengapa ini terjadi? Karena pada dokumen tersebut ada JavaScript yang baru akan dieksekusi saat dokumen sudah selesai di download. Penampakan scriptnya seperti berikut:

Fungsi JavaScript tersebut yang akan merender kembali sebagian elemen ke halaman dokumen. Jadi, memang ada sebagian elemen yang oleh programmernya sengaja disusun agar tidak dirender secara langsung oleh Web Browser ... :)

Dari pengalaman saya pribadi, sejauh ini saya temukan ada 2 teknik yang digunakan untuk merender kembali elemen pada dokumen HTML. Keduanya sama-sama menggunakan JavaScript. Yang pertama, data elemen yang akan di render disimpan pada variabel (seperti kasus pada situs di atas), kedua data diambil melalui JSON baru kemudian dirender. Contoh variabel untuk kasus di atas:

Solusinya mungkin tidak terlalu sulit. Mas @Awe bisa mencoba mencari teks tertentu (parsing) dari objek body.InnerHTML. Misalkan untuk harga barang, cari teks "final":, untuk stok barang, cari teks "in_stock" (semua teks termasuk tanda petik/kutip). Misalkan saja:

...
Set xHTMLDoc = xIE.Document
sBuffer = xHTMLDoc.body.innerHTML
sKey = Chr$(34) & "final" & Chr$(34) & Chr$(58)
lPos = InStr(1, sBuffer, sKey) 

If lPos Then
  sTemp = Mid(sBuffer, lPos + Len(sKey), 50)   
  sTemp = Mid(sTemp, 1, InStr(1, sTemp, Chr$(44)) - 1)
  Sheet1.Cells(2, 3) = CDbl(sTemp)
End If
...

Konsep alur prosesnya ± seperti itu. Silahkan dicoba dahulu. Jika sudah pusing, nanti saya buatkan contoh script. Dan tolong, jangan frustasi ... ;)

Demikian.

@Caton ...Karena pada dokumen tersebut ada JavaScript yang baru akan dieksekusi saat dokumen sudah selesai di download...

Ooo gitu toh...

terus kenapa IE tidak mengeksekusi JavaScript tersebut mas ?

btw, tengkiu infonya mas

@manweljs_ ... terus kenapa IE tidak mengeksekusi JavaScript tersebut mas ...

Karena script JS tersebut memang dipasang agar terpicu saat dokumen sudah lengkap (biasanya dalam JQuery memanfaatkan event $(document).ready atau pada JS memanfaatkan event window.onload. Jadi, saat semua elemen sudah terloading, yakni elemen:

<!DOCTYPE html>
...
</html>

dan seluruh elemen di dalam tag html tersebut selesai diloading dan dirender, maka script tersebut baru dieksekusi. IE sendiri tetap mengeksekusi JS tersebut, namun masalahnya, objek IE hanya memicu even saat dokumen lengkap diloading saja, tidak saat proses yang dikerjakan melalui JS selesai (mungkin bisa saja dengan trik-trik tertentu, namun sejauh ini saya belum menemukan caranya).

Demikian.

@Caton Konsep alur prosesnya ± seperti itu.

mas nanya lagi yak,

mengenai :

sBuffer = xHTMLDoc.body.innerHTML
sKey = Chr$(34) & "final" & Chr$(34) & Chr$(58)

skrip contoh diatas sudah saya coba dan berhasil, namun saya heran aja kalo nilai dari sBuffer saya letakan pada salah satu sel, kemudian saya cari manual kata "final" menggunakan FIND atau SEARCH kok gak ketemu yak ? (^_^)/

@manweljs_ ... kalo nilai dari sBuffer saya letakan pada salah satu sel, kemudian saya cari manual kata "final" menggunakan FIND atau SEARCH kok gak ketemu ...

Setiap sel hanya dapat menampung maksimal 32,767 karakter. Sementara sBuffer tersebut menampung sekitar 99,927 karakter.

Demikian.

@Caton Setiap sel hanya dapat menampung maksimal 32,767 karakter. Sementara sBuffer tersebut menampung sekitar 99,927 karakter.

I see!

thanks

@awe

berikut contoh skrip untuk harga lama dan harga baru, untuk status saya kurang paham yang mana yang diambil jadi silahkan dikembangkan ;)

Sub GetFromWeb()
Dim Ie As New InternetExplorer
Dim Doc As HTMLDocument
Dim lIdx As Long

lIdx = Range("A" & Rows.Count).End(xlUp).Row
For i = 2 To lIdx
    With Ie
        .Visible = False
        .navigate Cells(i, 1).Value
    Do
        DoEvents
    Loop Until .readyState = READYSTATE_COMPLETE
    
    Set xHTMLDoc = .document
    sBuffer = xHTMLDoc.body.innerHTML
    HargaLama = Chr$(34) & "list" & Chr$(34) & Chr$(58)
    HargaBaru = Chr$(34) & "final" & Chr$(34) & Chr$(58)
    Idx1 = InStr(1, sBuffer, HargaLama)
    Idx2 = InStr(1, sBuffer, HargaBaru)

    If Idx1 Then
      sTemp = vbNullString
      sTemp = Mid(sBuffer, Idx1 + Len(HargaLama), 50)
      sTemp = Mid(sTemp, 1, InStr(1, sTemp, Chr$(44)) - 1)
      Sheet1.Cells(i, 3) = sTemp
    End If
    If Idx2 Then
      sTemp = vbNullString
      sTemp = Mid(sBuffer, Idx2 + Len(HargaBaru), 50)
      sTemp = Mid(sTemp, 1, InStr(1, sTemp, Chr$(44)) - 1)
      Sheet1.Cells(i, 5) = sTemp
    End If
    End With
Next i
End Sub

sorry ada update sedikit, pengaruh copy paste (^_^)/

@awe ... Apakah saya ada menloncatkan action cek status stok dari script ini atau gimana mas ...

Seperti yang saya jelaskan, jika mas @Awe mencoba mencari ke dalam elemen HTML Document, besar kemungkinan tidak akan menemukan elemen yang dicari. Sebenarnya, untuk status stok ini saya sudah kasih petunjuk pada penjelasan awal saya di atas:

... untuk stok barang, cari teks "in_stock" ...

Coba perhatikan gambar berikut:

Periksa 2 baris di atas baris yang ditandai, ada 2 variabel data di situ, "in_stock" dan "in_limited_stock". Jadi untuk memeriksa ketersediaan stok, cukup cari teks in_stock. Nilainya berupa TRUE (tersedia) atau FALSE (tidak tersedia). Jika stok merupakan stok terbatas, maka cari teks in_limited_stock yang nilainya juga Boolean. Sedangkan jumlah stoknya, dapat mencari teks "limited_stock" dengan nilai numerik.

Jadi, dengan konsep alur proses yang sudah saya sampaikan dan sudah diimplementasikan oleh mas @manweljs_ di atas, mas @Awe dapat mencari data yang diinginkan. Misalkan untuk status stok barang ± dicari dengan cara yang serupa:

...
sKey = Chr$(34) & "in_stock" & Chr$(34) & Chr$(58)
lPos = InStr(1, sBuffer, sKey) 

If lPos Then
  sTemp = Mid(sBuffer, lPos + Len(sKey), 50)   
  sTemp = Mid(sTemp, 1, InStr(1, sTemp, Chr$(44)) - 1)
  '+-- Periksa apakah stok tersedia:
  If Cbool(sTemp) Then
    Sheet1.Cells(2, 3) = "Stok Tersedia"
  Else
    Sheet1.Cells(2, 3) = "Stok Tidak Tersedia"
  End IF
End If
...

Demikian.

@awe ...Akhirnya saya sudah bisa dan menemukan semua yang saya perlukan....

selamat ya

jangan ragu kalo mau mampir lagi ;)

@awe

itu "In_stok" nya ada 4, "final" nya pun ada 4 saya jadi bingung mau diambil yang mana.

kalo ide saya tahapannya kira-kira seperti ini :

1. hitung ada berapa keyword "in_stok" dari sBuffer (contohnya 4)
2. replace keyword dengan nilai atau karakter unik sebagai keyword baru, (misalnya target nya adalah "in_stok" yang ke 4 di ganti dengan "#iniTARGETNYA#"
3. Ulangi pencarian dengan keyword baru tersebut
4. seterusnya sama seperti sebelumnya

namun yang pertama kali harus ditentukan adalah :
kalau keywordnya lebih dari 1 maka yang ke berapa yang diambil