rumus saldo total otomatis

  1. 3 minggu lalu

    min mau tanya tentang rumus saldo akhir yang automatis terupdate nilainya ketika saldo sementara terisi. file terlampir.
    terimakasih sebelumnya.

  2. Caton

    Nov 15 Terverifikasi Indonesia + 19.288 Poin

    @artha ...

    Coba gunakan salah satu formula berikut :

    =LOOKUP(2;1/($E$4:$E$8>0);$E$4:$E$8)
    
    =INDEX($E$4:$E$8;SUMPRODUCT(MAX(($E$4:$E$8>0)*(ROW($E$4:$E$8)-3))))
    
    =INDEX($E$4:$E$8;AGGREGATE(14;7;(1/($E$4:$E$8>0))*(ROW($E$4:$E$8)-3);1))

    Ubah notasi ($E$4:$E$8>0) menjadi ($E$4:$E$8<>"") jika ingin nillai 0 (nol) juga disertakan. Semoga sesuai.

    Demikian.

  3. makasih min..

  4. min blh tnya artinya apa ya rumusnya maksutnya penjelasannya...makasihh

    yang pake lookup min

  5. Caton

    Nov 17 Terverifikasi Indonesia + 19.288 Poin

    @artha ...

    Saya bukan Admin atau Mimin...! Formula :

    =LOOKUP(2;1/($E$4:$E$8>0);$E$4:$E$8)

    tujuannya untuk mencari (posisi) nilai 2 di dalam vektor pencarian yang ditentukan (yakni 1/($E$4:$E$8>0)) dan mengembalikan hasil berupa salah satu nilai pada vektor hasil (yakni $E$4:$E$8) sesuai indeks posisi yang ditemukan. Ilustrasinya :

    =LOOKUP(2;1/($E$4:$E$8>0);$E$4:$E$8)
    =LOOKUP(2;{1;1;1;#DIV/0!;#DIV/0!};{30000000;30664830;30314830;0;0})

    Karena fungsi LOOKUP tidak menemukan nilai 2 dalam vektor pencarian berikut :

    {1;1;1;#DIV/0!;#DIV/0!}

    maka, fungsi LOOKUP akan mengembalikan kurang dari nilai yang dicari. Pada vektor pencarian di atas, fungsi LOOKUP mengabaikan nilai #DIV/0! dan hanya mengembalikan nilai 1 terakhir yang ditemukan. Ilustrasinya :

    1/($E$4:$E$8>0)
    {1;1;1;#DIV/0!;#DIV/0!}
    {*;*;1;*;*}
    
    Tanda * mengilustrasikan nilai yang diabaikan.

    Dari ilustrasi di atas, diketahui posisi nilai 1 terakhir berada pada indeks ke-3, yang jika dikorelasikan ke vektor hasil $E$4:$E$8 maka akan menghasilkan nilai pada sel E6.

    Demikian.

 

atau Mendaftar untuk ikut berdiskusi!