1. 4 minggu lalu

    Selamat malam semua,

    mohon bantuannya untuk membuat semacem search yang berdasarkan database lokal untuk menampilkan 14 jenis data berdasarkan 1 dari 2 kriteria (mohon maaf kalau deskripsi ini salah, krn saya sendiri bingung menjelaskannya)
    Biar lebih jelas, saya lampirkan file
    Terima kasih banyak atas bantuan para master sekalian
    Book14.11.xlsx

  2. 3 minggu lalu

    Caton

    Nov 16 Terverifikasi Indonesia + 15.163 Poin

    @ZiedCassius ...

    Ada beberapa trik untuk dapat melakukan pencarian pada 2 kolom atau lebih. Namun, pada dasarnya kita perlu menentukan terlebih dahulu apakah pencarian akan dilakukan berdasarkan baris data atau kolom data terlebih dahulu.

    Sebagai contoh, pada tabel data berikut,

    contoh-tabel.png

    kolom B dan kolom C merupakan kolom pencarian datanya. Pengguna dapat memasukkan data yang akan dicari berupa salah satu dari data NIK1 atau NIK2 pada sel H3. Dari tabel tersebut, bila data akan dicari perbaris, maka dapat digunakan fungsi MATCH seperti berikut :

    =IF(LEN($H$3);IFERROR(MATCH($H$3&"";$B$3:$B$11;0);IFERROR(MATCH($H$3&"";$C$3:$C$11;0);""));"")

    Pada formula di atas, jika data yang dicari tidak ditemukan pada kolom B (range B3:B11), maka data akan dicari pada kolom C (range C3:C11). Jika data tidak ditemukan pada kedua kolom (range tsersebut), maka hasilnya akan kosong.

    Pada contoh di atas, sel L3 akan berisi indeks baris data jika data yang dicari ditemukan. Untuk mengambil data pada kolom lainnya dalam indeks baris yang ditemukan oleh fungsi MATCH tersebut, maka gunakan fungsi INDEX, misalkan untuk Nama menggunakan formula seperti berikut :

    =IF(ISNUMBER($L$3);INDEX($D$3:$E$11;$L$3;1);"")

    Salah satu keuntungan dari formula di atas adalah kolom atau range pencarian data tidak harus berdampingan.

    Selain dengan menggunakan fungsi MATCH dan INDEX, bisa juga menggunakan fungsi SUMPRODUCT untuk menentukan kolom sumber data, dan fungsi VLOOKUP untuk menemukan datanya, misalkan dengan formula berikut untuk menentukan kolomnya:

    =MIN(SUMPRODUCT(MAX((($B$3:$B$11=$H$3)*1)+(($C$3:$C$11=$H$3)*2)));2)

    dan fungsi berikut untuk menemukan datanya :

    =IF($L$3;VLOOKUP($H$3;CHOOSE($L$3;$B$3:$E$11;$C$3:$E$11);3-($L$3=2);0);"")

    Contoh formula terakhir ini sebaiknya digunakan untuk kolom atau range pencarian data yang berdampingan.

    Silahkan dipelajari dari file terlampir. Semoga sesuai.

    Demikian.

  3. sesuai banget mas..
    terima kasih @Caton

 

atau Mendaftar untuk ikut berdiskusi!