mohon bantu memasukkan gambar

  1. 5 minggu lalu

    maaf master saya masih belum bisa memasukkan gambar ke image userform show atau activate. sebagai ilustrasi saya lampirkan screen short pada file terlampir
    pejelasan :
    saat userform show saya berharap pada image muncul gambar secara otomatis bukan melalaui property di mana gambar bersumber pada sebuah folder di dokumen (drive c)
    Nama file : pisang.JPG, Mangga.IPG, Bayam,jpg, Mentimun,JPG
    terima kasih sebelumnya

  2. 4 minggu lalu

    Caton

    Nov 9 Terverifikasi Indonesia + 15.164 Poin
    Di sunting 4 minggu lalu oleh Caton

    @waluyo ...

    Coba gunakan fungsi LoadPicture untuk memuat gambar ke dalam kontrol Image. Berikut beberapa contoh script untuk menampilkan gambar yang ada di folder ke dalam kontrol Image:

    Private Sub UserForm_Initialize()
        Dim sFolder As String
        
        sFolder = "d:\Data-Data\Gambar\"
        
        Set Image1.Picture = LoadPicture(sFolder & "strawberries.jpg")
        Set Image2.Picture = LoadPicture(sFolder & "pisang.jpg")
        Set Image3.Picture = LoadPicture(sFolder & "jeruk.jpg")
        Set Image4.Picture = LoadPicture(sFolder & "apel.jpg")
        Set Image5.Picture = LoadPicture(sFolder & "anggur.jpg")
    End Sub

    atau menggunakan script berikut :

    Private Sub UserForm_Initialize()
        Dim lX As Long, lY As Long
        Dim sFolder As String
        Dim xGambar
        
        xGambar = Array("strawberries.jpg", "pisang.jpg", "jeruk.jpg", "apel.jpg", "anggur.jpg")
        
        lY = 1
        sFolder = "d:\Data-Data\Gambar\"
        For lX = LBound(xGambar) To UBound(xGambar)
            Set Me.Controls("Image" & lY).Picture = LoadPicture(sFolder & xGambar(lX))
            lY = lY + 1
        Next        
    
    End Sub

    atau bisa juga seperti ini :

    Private Sub UserForm_Initialize()
        Dim sFolder As String
        Dim xCtrl As Control
        Dim lX As Long
        Dim xGambar
    
        xGambar = Split("strawberries.jpg|pisang.jpg|jeruk.jpg|apel.jpg|anggur.jpg", "|")
    
        lX = 0
        sFolder = "d:\Data-Data\Gambar\"
        For Each xCtrl In Me.Controls
            If lX <= UBound(xGambar) Then
                If TypeName(xCtrl) = "Image" Then
                    Set xCtrl.Picture = LoadPicture(sFolder & xGambar(lX))
                    lX = lX + 1                
                End If
            End If
        Next
    
    End Sub

    Demikian.

  3. terima kasih saya coba mudahan dapat

  4. terimakasih banyak master atas bantuannya sudah saya coba hasil ok

 

atau Mendaftar untuk ikut berdiskusi!