Cara vlookup ke kiri

  1. 7 minggu lalu

    Permisi juragan,

    Ane ada sedikit kebingungan soal excell, jadi ane mau cari no.register konsumen yang datanya ada di sheet data 2. Nah, setelah ane coba googling masih belum nemu rumus yang pas untuk vlookup kekiri. Mohon bantuannya. Oiya, ane pake openoffice dan wps.

  2. Caton

    Sep 27 Terverifikasi Indonesia + 12.498 Poin

    @siriki ... mau cari no.register konsumen yang datanya ada di sheet data 2. Nah, setelah ane coba googling masih belum nemu rumus yang pas untuk vlookup kekiri ...

    Yang mudah, bisa menggunakan fungsi INDEX + MATCH:

    =IFERROR(INDEX('DATA 2'!$B$2:$B$44; MATCH($B3; 'DATA 2'!$C$2:$C$44; 0)); "")

    atau kalau memang maunya dengan fungsi VLOOKUP:

    =IFERROR(VLOOKUP($B3; CHOOSE({1\2}; 'DATA 2'!$C$2:$C$44; 'DATA 2'!$B$2:$B$44);2;0);"")

    Demikian.

  3. @Caton Yang mudah, bisa menggunakan fungsi INDEX + MATCH:

    =IFERROR(INDEX('DATA 2'!$B$2:$B$44; MATCH($B3; 'DATA 2'!$C$2:$C$44; 0)); "")

    atau kalau memang maunya dengan fungsi VLOOKUP:

    =IFERROR(VLOOKUP($B3; CHOOSE({1\2}; 'DATA 2'!$C$2:$C$44; 'DATA 2'!$B$2:$B$44);2;0);"")

    Demikian.

    Gan, udah dicoba pakai yang index+match, itu masih belum bisa kenapa ya gan? hasilnya #NAME?

  4. Data anda ada yang dobel jadi rumusnya saya ganti, mudah2xan akurat

    Azumi

  5. @Azumi Data anda ada yang dobel jadi rumusnya saya ganti, mudah2xan akurat

    Azumi

    Rumusnya panjang juga ya gan. Btw,terimakasih. Problem solved.

  6. Caton

    Sep 28 Terverifikasi Indonesia + 12.498 Poin

    @siriki ... udah dicoba pakai yang index+match, itu masih belum bisa kenapa ya ...

    Maaf mas @siriki, sedikit saya koreksi formula yang saya berikan. Ada 2 hal yang menyebabkan kesalahan formula yang mas sebutkan:

    [1]. Pada OpenOffice, fungsi IFERROR tidak dikenal. Solusinya, ganti dengan fungsi IF + ISERROR.

    Solusinya, untuk dengan data seperti pada file terlampir, formula diubah menjadi dengan fungsi VLOOKUP + CHOOSE menjadi:

    = IF(ISERROR(VLOOKUP($B2&" "; CHOOSE({1\2}; 'DATA 2'!$C$2:$C$44; 'DATA 2'!$B$2:$B$44); 2; 0)); "";
      VLOOKUP($B2&" "; CHOOSE({1\2}; 'DATA 2'!$C$2:$C$44; 'DATA 2'!$B$2:$B$44); 2; 0))

    atau dengan fungsi INDEX + MATCH menjadi:

    = IF(ISERROR(INDEX('DATA 2'!$B$2:$B$44; MATCH($B2&" "; 'DATA 2'!$C$2:$C$44; 0))); "";
      INDEX('DATA 2'!$B$2:$B$44; MATCH($B2&" "; 'DATA 2'!$C$2:$C$44; 0)))

    [2]. Setiap baris data nama pada sheet DATA 2 mengandung karakter spasi pada akhir kata.

    Jika karakter spasi pada akhir nama pada setiap baris data sheet DATA 2 sudah dibuang, maka formula di atas tinggal diubah dengan membuang notasi &"" menjadi:

    = IF(ISERROR(VLOOKUP($B2; CHOOSE({1\2}; 'DATA 2'!$C$2:$C$44; 'DATA 2'!$B$2:$B$44); 2; 0)); "";
      VLOOKUP($B2; CHOOSE({1\2}; 'DATA 2'!$C$2:$C$44; 'DATA 2'!$B$2:$B$44); 2; 0))

    atau dengan fungsi INDEX + MATCH menjadi:

    = IF(ISERROR(INDEX('DATA 2'!$B$2:$B$44; MATCH($B2; 'DATA 2'!$C$2:$C$44; 0))); "";
      INDEX('DATA 2'!$B$2:$B$44; MATCH($B2; 'DATA 2'!$C$2:$C$44; 0)))

    Catatan: Formula sudah dicoba pada Excel 2010, WPS Spreadsheet 10.2 dan OpenOffice Cal 4.1.5 ...

    Demikian koreksi dari saya.

 

atau Mendaftar untuk ikut berdiskusi!