masih copy copy,,,

  1. 2 bulan yang lalu
    Di sunting 2 bulan yang lalu oleh wawan setiawan

    master yang saya tanyakan pada kasus ini bagaimana caranya copy otomatis dari sheet database ke sheet REKAP file yang saya lampirkan adalah copy sheet REKAP yang diharapkan,,,mhon pencerahannya master,,,,

  2. Caton

    Sep 20 Terverifikasi Indonesia + 12.602 Poin

    @wawan setiawan ... bagaimana caranya copy otomatis dari sheet database ke sheet REKAP ...

    Berikut contoh script yang dapat dicoba. Copy dan paste script berikut ke dalam modul standar yang sudah ada (atau tambahkan modul baru):

    Option Explicit
    
    Public Sub BuatRekapData()
        Dim lIdx As Long, lCount As Long, lRow As Long
        Dim sAddr As String, sValue As String
        
        lCount = Sheet6.Range("A" & Rows.Count).End(xlUp).Row
        lRow = Sheet7.Range("A" & Rows.Count).End(xlUp).Row + 1
        
        Application.ScreenUpdating = False
        Application.EnableEvents = False
        
        For lIdx = 2 To lCount
            Sheet7.Range("A" & lRow) = lRow - 1
            
            sAddr = Replace("T#, V#, W#", "#", lIdx)
            Sheet6.Range(sAddr).Copy
            Sheet7.Range("B" & lRow).PasteSpecial xlPasteValues
            
            sAddr = Replace("K#, X#", "#", lIdx)
            Sheet6.Range(sAddr).Copy
            Sheet7.Range("E" & lRow).PasteSpecial xlPasteValues
            
            Sheet7.Range("G" & lRow) = _
                Sheet6.Range("M" & lIdx) & " " & _
                Sheet6.Range("N" & lIdx) & " " & _
                Sheet6.Range("O" & lIdx)
            
            Sheet7.Range("H" & lRow) = _
                Sheet6.Range("P" & lIdx) & " " & _
                Sheet6.Range("Q" & lIdx) & " " & _
                Sheet6.Range("R" & lIdx)
            
            sAddr = Replace("I#, AB#", "#", lIdx)
            Sheet6.Range(sAddr).Copy
            Sheet7.Range("I" & lRow).PasteSpecial xlPasteValues
            
            sAddr = Replace("Y#, Z#, AA#", "#", lIdx)
            Sheet6.Range(sAddr).Copy
            Sheet7.Range("K" & lRow).PasteSpecial xlPasteValues
            
            sValue = Replace("SUM(@J#:@M#)", "@", "'" & Sheet7.Name & "'!")
            sValue = Replace(sValue, "#", lIdx)
            Sheet7.Range("N" & lRow) = Application.Evaluate(sValue)
            
            lRow = lRow + 1
        Next
        
        With Sheet7
            .Select
            .Range("A" & lRow).Select
        End With
        
        Application.CutCopyMode = False
        Application.EnableEvents = True
        Application.ScreenUpdating = True
    End Sub

    Assign tombol COPY pada sheet DATABASE ke prosedur Sub BuatRekapData tersebut. Simpan file dalam format Macro Enabled (xlsm atau xlsb).

    Demikian.

  3. mksh master@caton dah bntu kesekian kalinya,,,saya akan coba

  4. master @ Caton sudah saya coba dan memang benar hasil copy dari Sheet DATABASE RangeT2:AB2 di posisi cel B2 di sheet REKAP akan tetapi yang dimaksud saya target Range AC2:AJ2 (pengikut1) saya ingin tercopy juga di row selanjutnya atau cel B3 di sheet REKAP kemudian range AK2:AR2 (pengikut2)juga sama tercopy di cel B4 yang terakhir Range AS2:AJ2(pengikut3) tercopy di cel B4 di Sheet REKAP,,,
    intinya Colom T (Nama),Kolom AC (Pengikut1), kolom AK(pengikut2)dan kolom AS(pengikut3) itu kan di satu baris ya master,,,nah yang saya maksud kolom AC (Pengikut1), kolom AK(pengikut2)dan kolom AS(pengikut3) juga tercopy di row selanjutnya,,,kira2 bisa tidak ya,,1 baris data tp hasil copy sebagian ke row selanjutnya,,,mhon solusinya master

  5. kalo bagian script For lIdx = 2 To lCount, 2 artinya apa ya master Caton?

  6. 9 minggu lalu

    Caton

    Sep 22 Terverifikasi Indonesia + 12.602 Poin

    @wawan setiawan ... Range AC2:AJ2 (pengikut1) saya ingin tercopy juga di row selanjutnya atau cel B3 di sheet REKAP kemudian range AK2:AR2 (pengikut2)juga sama tercopy di cel B4 yang terakhir Range AS2:AJ2(pengikut3) tercopy di cel B4 di Sheet REKAP ...

    Terlampir contohnya.

    @wawan setiawan ... kalo bagian script For lIdx = 2 To lCount, 2 artinya apa ya ...

    Baris kedua sheet DATABASE.

    Demikian.

  7. 8 minggu lalu

    sipp master @caton ,,,sudah dicoba hasil memuaskan ,,,thks,,,

 

atau Mendaftar untuk ikut berdiskusi!