2 KRITERIA

  1. 5 bulan yang lalu

    MOHON BANTUANNYA UNTUK 2 KRITERIA SUHU TERLAMPIR

    @manweljs_ dan @Septian Saputra ...

    Saya ikut menambahkan dengan formula berbeda untuk Sheet 2:

    =VLOOKUP($C6;Sheet1!$A$4:$GL$59;MATCH($A6;Sheet1!$B$3:$GL$3;0)+1)

    atau dengan fungsi INDEX + MATCH:

    =INDEX(Sheet1!$B$4:$GK$59;MATCH($C6;Sheet1!$A$4:$A$59;0);MATCH($A6;Sheet1!$B$3:$GL$3;0))

    Demikian.

  2. Caton

    Jul 26 Terverifikasi Indonesia + 13.255 Poin

    @Septian Saputra ...

    2 kriteria untuk apa? Filenya menghilang... (^_^)/ :D

  3. SOAL.xlsx

  4. manweljs_

    Jul 26 Terverifikasi + 6.199 Poin
    Di sunting 5 bulan yang lalu oleh manweljs_

    @Septian Saputra

    saya sebenarnya kurang paham yang ditanyakan karena anda kurang berusaha untuk menjelaskan soalan tersebut. coba periksa file terlampir, jika bukan demikian maksud anda silahkan dijelaskan lebih jauh.

    atau silahkan ditunggu contoh lain menggunakan SUMPRODUCT

  5. Caton

    Jul 26 Terverifikasi Jawaban Terpilih Indonesia + 13.255 Poin

    @manweljs_ dan @Septian Saputra ...

    Saya ikut menambahkan dengan formula berbeda untuk Sheet 2:

    =VLOOKUP($C6;Sheet1!$A$4:$GL$59;MATCH($A6;Sheet1!$B$3:$GL$3;0)+1)

    atau dengan fungsi INDEX + MATCH:

    =INDEX(Sheet1!$B$4:$GK$59;MATCH($C6;Sheet1!$A$4:$A$59;0);MATCH($A6;Sheet1!$B$3:$GL$3;0))

    Demikian.

  6. manweljs_

    Jul 26 Terverifikasi + 6.199 Poin

    tumben SUMPRODUCT nya gak ikut mas :)

  7. Caton

    Jul 26 Terverifikasi Indonesia + 13.255 Poin
    Di sunting 5 bulan yang lalu oleh Caton

    @manweljs_ ...

    Sebenarnya, saya cuma pengen ngasih tambahan formula dengan fungsi "standar" saja, tanpa Array Formula. Dua formula itu juga saya kira cukup. Klo mau pake Array Formula, khan sudah ada punya mas @manweljs_ ... Untuk formula dengan fungsi SUMPRODUCT, lebih sederhana lagi:

    =SUMPRODUCT((db.Loc=$A6)*(db.Desc=$C6);db.Data)

    dimana :

    db.Data = Sheet1!$B$4:$GK$59
    db.Desc = Sheet1!$A$4:$A$59
    db.Loc  = Sheet1!$B$3:$GK$3

    Atau pake fungsi SUMIF tanpa Array Formula:

    =SUMIF(db.Loc;A6;INDEX(db.Data;MATCH(C6;db.Desc;0);0))

    Nah, terserah TS mau pake formula yang mana... :D

  8. manweljs_

    Jul 27 Terverifikasi + 6.199 Poin

    OFFSET :

    =OFFSET(Sheet1!$A$1;MATCH($C6;Sheet1!$A:$A;0)-1;MATCH($A6;Sheet1!$3:$3;0)-1)

  9. Caton

    Jul 27 Terverifikasi Indonesia + 13.255 Poin
    Di sunting 5 bulan yang lalu oleh Caton

    Gak sekalian ditambahin pake fungsi INDIRECT mas @manweljs_ ... ;)

  10. manweljs_

    Jul 27 Terverifikasi + 6.199 Poin
    Di sunting 5 bulan yang lalu oleh manweljs_

    INDIRECT & ADDRESS :

    =INDIRECT("Sheet1!"&SUBSTITUTE(ADDRESS(1;MATCH($A6;Sheet1!$3:$3;0);4);1;"")&SUBSTITUTE(ADDRESS(MATCH($C6;Sheet1!$A:$A;0);1;4);"A";""))

    kalau pakai VBA bisa gak ya mas @Caton :D :P

  11. Caton

    Jul 27 Terverifikasi Indonesia + 13.255 Poin

    Mas @manweljs_ ...

    Terbaik...! Ehm, klo pake VBA sepertinya boleh juga tuh dibuatin, mungkin TS-nya juga butuh... :)

    @Septian Saputra ...

    Udah sesuai belum solusinya? Kasih masukan sudah sesuai atau belum, jangan cuma dilihatin saja diskusinya. Klo perlu pake macro, mas @manweljs_ seperti siap untuk memberikan solusinya... :D

  12. @Caton Terima Kasih Sebelumnya tapi saya coba ngak ketemu mas saya coba pake rumus =VLOOKUP($C6;Sheet1!$A$4:$GL$59;MATCH($A6;Sheet1!$B$3:$GL$3;0)+1)
    Coba kirim file excelnya mas

    untuk@manweljs_ Terima Kasih Mas

    Untuk VBA saya kurang paham mas

  13. Caton

    Jul 27 Terverifikasi Indonesia + 13.255 Poin

    @Septian Saputra ...

    Terlampir contoh formula dengan semua fungsi yang sudah saya sampaikan dan saya buat ...
    Demikian, semoga sesuai... :)

 

atau Mendaftar untuk ikut berdiskusi!