rumus mid

  1. 10 bulan yang lalu

    mohon bantuan untuk mengambil angka yg saya warna merah gimana,ya?
    sudah saya coba pake rumus MID,tapi tidak sesuai
    perlu tambahan rumus apakah?
    berikut saya lampirkan capture
    trimaksih sbelumnya

  2. Caton

    9 Peb 2018 Terverifikasi Indonesia + 13.255 Poin

    Coba mas @Goral gunakan formula sebagai berikut:

    =LEFT(MID(A1;SEARCH("#";A1)+1;100);SEARCH("#";MID(A1;SEARCH("#";A1)+1;100))-1)*1

    dengan asumsi teks berada pada kolom A, dimulai dari sel A1. Demikian... ;)

  3. trimakasih,mas..alhamdulillah teratasi
    bisa minta penjelasan rumusnya maksudnya bagaimanakah?
    terutama rumus : SEARCH("#";A1)+1;100)
    angka 100 dirumus fungsinya buat apaya mas?

  4. mas @Caton ,ada rekomendasi beli buku buat belajar rumus2?
    :)

  5. Caton

    9 Peb 2018 Terverifikasi Indonesia + 13.255 Poin

    Formula tersebut di atas jika diurai, terdiri dari 2 fungsi utama, LEFT dan MID. Misalkan saja, pada sel A1 terdapat nilai 5676#115#444/2018 dan target nilai yang diinginkan adalah 115, maka pertama adalah membuang bagian awal teks 5676# terlebih dahulu. Formulanya:

    =MID(A1;SEARCH("#";A1)+1;100)
    =MID("5676#115#444/2018";SEARCH("#";"5676#115#444/2018")+1;100)
    =MID("5676#115#444/2018";5+1;100)
    =MID("5676#115#444/2018";6;100)
    ="115#444/2018"

    Oleh karena panjang karakter tidak tetap, maka argumen untuk Num_Chars pada fungsi MID diisi dengan nilai estimasi yakni 100 (untuk mengambil seluruh karakter tersisa). Dalam hal ini, fungsi MID akan mengembalikan karakter sejumlah karakter tersisa jika argumen Num_Chars lebih besar dari panjang karakter tersisa. Misalkan saja:

    = MID("AABBCC";2;4) = "ABBC"
    = MID("AABBCC";3;10) = "BBCC"
    = MID("AABBCC";2;100) = "ABBCC"

    Tahap kedua adalah membuang bagian akhir teks #444/2018. Formulanya:

    =LEFT(MID(A1;SEARCH("#";A1)+1;100);SEARCH("#";MID(A1;SEARCH("#";A1)+1;100))-1)*1
    =LEFT("115#444/2018";SEARCH("#";"115#444/2018")-1)*1
    =LEFT("115#444/2018";4-1)*1
    =LEFT("115#444/2018";3)*1
    ="115"*1
    =115

    Demikian penjelasan mengenai alur formulasinya. Mengenai buku, maaf, saya tidak punya rekomendasi buku-buku bacaan Excel yang bisa dibeli. Saya biasanya langsung nyari di Excel Help, atau tanya om Google atau baca-baca artikel internet, atau baca ebook Excel... ;)

  6. trims,mas..saya mulai paham,tadi juga sempet cari2 penjelasan nya di diskusi yg lain
    ooow,.jadi online trus ya.mas :)

 

atau Mendaftar untuk ikut berdiskusi!