Rumus Matching data dari 2 sheet berbeda

  1. 9 bulan yang lalu

    Buat para Master Excel, saya minta bantuannya.
    saya ingin me-matching kan 2 data yang berasal dari sheet 1 dan sheet 2.
    Tetapi hasil matching nya di sheet 3

    sheet 1 berupa = Nama murid + No Induk + No KTP
    sheet 2 berupa = Nama Murid + No Ktp + No Handphone
    sheet 3 (sheet hasil matching) berupa = Nama murid + No Induk + No Ktp + No HP

    bagaimana rumus membuat matching data nya & bagaimana cara memunculkan data yang dibutuhkan

    Terimakasih sebelumnya

    Mungkin ada banyak cara, namun mas @Zikafrihadi bisa mencoba dahulu file terlampir... ;)

  2. Caton

    14 Des 2017 Terverifikasi Jawaban Terpilih Indonesia + 11.522 Poin

    Mungkin ada banyak cara, namun mas @Zikafrihadi bisa mencoba dahulu file terlampir... ;)

  3. @Caton Mungkin ada banyak cara, namun mas @Zikafrihadi bisa mencoba dahulu file terlampir... ;)

    wahhhh masss.. terimakasih banyak. saya coba otak atik dulu sesuai data yg saya butuhkan
    mohon bimbinganya suhu

  4. Caton

    14 Des 2017 Terverifikasi Indonesia + 11.522 Poin

    Sama-sama mas @Zikafrihadi... Diskusikan saja kembali jika ada kendala, masalah atau formula yang tidak tepat... ;)

  5. @Caton : maaf master, bisa di jelasin detail ga perihal rumus ini?
    saya udh mengikuti tapi gagal

    =IFERROR(IF(INDEX(Data1,MATCH(B4,INDEX(Data1,0,1),0),3)=INDEX(Data2,MATCH(B4,INDEX(Data2,0,1),0),3),INDEX(Data1,MATCH(B4,INDEX(Data1,0,1),0),3),""),"")

  6. Caton

    14 Des 2017 Terverifikasi Indonesia + 11.522 Poin
    Di sunting 9 bulan yang lalu oleh Caton

    Maaf mas @Zikafrihadi ... Sebenarnya, cara termudah untuk mendapatkan hasil yang diinginkan adalah dengan VLOOKUP atau INDEX+MATCH saja (periksa file terlampir). Karena mas @Zikafrihadi bertanya dengan bagaimana proses kalkulasi dari formula yang digunakan pada lampiran file sebelumnya, saya coba jelaskan sedikit sebagai berikut:

    Inti dari formula tersebut adalah fungsi IF dan fungsi INDEX+MATCH. Pada formula di atas, nama range Data1 merujuk ke range B4:E13 pada sheet Data_1, dan nama range Data2 merujuk ke range B4:E14 pada sheet Data_2. Saya harap mas @Zikafrihadi memahami fungsi INDEX dan MATCH, agar uraiannya tidak terlalu panjang. Kita urai per bagian untuk formula dengan fungsi IF. Formula dari argumen Logical Test pada fungsi IF tersebut adalah:

    INDEX(Data1;MATCH(B4;INDEX(Data1;0;1);0);3)=INDEX(Data2;MATCH(B4;INDEX(Data2;0;1);0);3)

    Formula di atas pada dasarnya sama, yang membedakannya adalah range acuan pencarian datanya. Untuk sel D4 sheet Data_3, nilai yang dicari adalah sama yakni nilai pada sel B4, "Ahmad". Dengan demikian formula:

    = INDEX(Data1;MATCH(B4;INDEX(Data1;0;1);0);3)
    = INDEX(Data1;4;3)
    = 36789046

    dan formula:

    = INDEX(Data2;MATCH(B4;INDEX(Data2;0;1);0);3)
    = INDEX(Data2;7;3)
    = 36789046

    menghasilkan nilai yang sama, yakni 36789046. Sehingga argumen Logical_Test pada fungsi IF tersebut akan menjadi:

    = IF(36789046=36789046;INDEX(Data1;MATCH(B4;INDEX(Data1;0;1);0);3);"")
    = IF(TRUE;INDEX(Data1;MATCH(B4;INDEX(Data1;0;1);0);3);"")
    = IF(TRUE;INDEX(Data1;4;3);"")
    = IF(TRUE;36789046;"")
    = 36789046

    Saya jelaskan sedikit tentang fungsi INDEX dan fungsi MATCH yang digunakan. Pada formula di atas, fungsi MATCH yang digunakan:

    MATCH(B4;INDEX(Data1;0;1);0)

    dan

    MATCH(B4;INDEX(Data2;0;1);0)

    akan mencari nilai pada sel B4 ("Ahmad") pada kolom pertama dari masing-masing range acuan (Data1 dan Data2). Formula:

    INDEX(Data1;0;1)

    bertujuan untuk mengambil seluruh baris nilai dari kolom ke-1 pada range Data1. Hal ini terjadi oleh karena argumen Row_Num pada fungsi INDEX tersebut kita isi dengan nilai 0 (nol). Hasilnya akhir dari fungsi INDEX tersebut akan berupa array:

    = INDEX(Data1;0;1)
    = {"Kiki";"Teguh";"Aris";"Ahmad";"Aji";"Raya";"Farhan";"Iqbal";"Deden";"Umam"}

    dan

    = INDEX(Data2;0;1)
    = {"Iqbal";"Deden";"Umam";"Kiki";"Teguh";"Aris";"Ahmad";"Aji";"Raya";"Farhan";"Nugraha"}

    Dengan demikian, fungsi INDEX terhadap range Data1 akan menjadi:

    = INDEX(Data1;MATCH(B4;INDEX(Data1;0;1);0);3)
    = INDEX(Data1;MATCH("Ahmad";{"Kiki";"Teguh";"Aris";"Ahmad";"Aji";"Raya";"Farhan";"Iqbal";"Deden";"Umam"};0);3)
    = INDEX(Data1;4;3)
    = 3678904

    Demikian uraian prosesnya. Btw, semua formula yang digunakan pada file terlampir memiliki kelemahan yang sama, yakni jika ada data Nama yang sama, maka hasilnya akan tidak akurat. Menurut saya, yang terbaik adalah dengan mencari data berdasarkan nilai kolom KTP, karena pada dasarnya Nomor KTP bersifat unik tanpa duplikasi. Namun, tentunya kolom KTP tersebut harus ada pada masing-masing sheet (Data_1 dan Data_2). Mungkin nanti jika ada kasusnya baru dicarikan kembali solusinya... :D

  7. @Caton : maaf mas saya masih newbie, kebetulan dapat pekerjaan seperti ini
    ini gambaran kasus yang saya hadapi
    mohon dibantu mas. trims

  8. wuih, lengkap banget master @Caton kalo jawab... belajar lagi ah....

    Om @zikafrihadi data excel nya masih kurang jelas maksudnya...
    itu kan ada 3 sheet, 1, 2 dan 3, coba di sheet ke tiga dituliskan contoh jawabannya secara manual dulu, biar tahu pengennya gimana... jawabannya master caton kan dah komplit... kurang apanya coba...

  9. Caton

    14 Des 2017 Terverifikasi Indonesia + 11.522 Poin

    Saya setuju dengan saran mas @Irsyad K ... Ada baiknya mas @Zikafrihadi berikan target hasil yang diinginkan agar bisa dipahami dan dicarikan solusi terbaiknya... Namun, saya coba dahulu dengan file terlampir. Mungkin saja sesuai harapan... ;)

  10. @Caton mas boleh minta kontak person nya? soalnya saya masih blum ktemu data yg diinginkan

  11. Caton

    15 Des 2017 Terverifikasi Indonesia + 11.522 Poin

    Data apa yang dimaksud? Hasil dari file yang saya upload terakhir atau file datanya mas @Zikafrihadi ?

 

atau Mendaftar untuk ikut berdiskusi!