ada rumus remove duplicate otomatis gak ya?

  1. 11 bulan yang lalu

    minta solusinya para master excel

    saya punya data yang tiap bulan tambah, bisa dengan nama orang yang sama perbulan/ perminggu.
    yang saya ingin tanyakan, bisa nggak dikolom kuning di file excel saya ini dibuat otomatis, jadi tiap tambah data unik yang baru (nama baru), otomatis tambah pula data dikolom kuning (kolom kuning digunakan untuk menghitung countif). terima kasih..

    Mungkin maksudnya membuat daftar unik dari data yang ada duplikasi datanya?! Coba file terlampir. Formulasinya menggunakan Array Formula, jadi perhatikan jumlah data yang akan diperiksa. Sebaiknya, kolom data yang dibuat acuan (kolom C) komparasi dirujuk melalui Nama Range dinamis saja daripada merujuk ke seluruh baris pada kolom tersebut. Dengan demikian, meskipun data bertambah, ukuran range acuannya tidak terlalu banyak... Semoga sesuai.

  2. Caton

    9 Des 2017 Terverifikasi Jawaban Terpilih Indonesia + 12.602 Poin

    Mungkin maksudnya membuat daftar unik dari data yang ada duplikasi datanya?! Coba file terlampir. Formulasinya menggunakan Array Formula, jadi perhatikan jumlah data yang akan diperiksa. Sebaiknya, kolom data yang dibuat acuan (kolom C) komparasi dirujuk melalui Nama Range dinamis saja daripada merujuk ke seluruh baris pada kolom tersebut. Dengan demikian, meskipun data bertambah, ukuran range acuannya tidak terlalu banyak... Semoga sesuai.

  3. terima kasih master Caton,
    sekalian belajar :)

  4. Caton

    9 Des 2017 Terverifikasi Indonesia + 12.602 Poin

    Sama-sama mas @Irsyad K... semoga bermanfaat ;)

  5. master @Caton rumus yang ini gimana mbacanya ya... dah 3 hari belajar masih belum paham. terutama match (0 kok bisa 0 ??
    '{=IFERROR(INDEX(CountRange;MATCH(0;COUNTIF($I$2:I8;CountRange);0));"")}

    maaf master caton ngrepotin.

  6. Caton

    12 Des 2017 Terverifikasi Indonesia + 12.602 Poin

    Begini mas @Irsyad k .... Kita urai dahulu formula:

    =IFERROR(INDEX(CountRange;MATCH(0;COUNTIF($I$2:I2;CountRange);0));"")

    Formula di atas pada dasarnya menggunakan fungsi INDEX + MATCH, dengan range yang diacu adalah range dinamis dengan nama CountRange. CountRange sendiri (pada file yang saya lampirkan) mengacu kepada range C3:C82, dan akan berubah sesuai jumlah baris data pada kolom C. Agar tidak terlalu panjang uraiannya, saya asumsikan saja CountRange merujuk kepada range C3:C7 dengan data:

    Boyolali, Boyolali, Klaten, Sleman, Sleman

    Dengan asumsi CountRange seperti tersebut di atas, maka formula:

    = COUNTIF($I$2:I2;CountRange) 
    = COUNTIF("Kota / Kabupaten";CountRange)
    = COUNTIF("Kota / Kabupaten";{"Boyolali";"Boyolali";"Klaten";"Sleman";"Sleman"})
    = {0;0;0;0;0}

    Oleh karena argumen Criteria pada fungsi COUNTIF di atas berupa array (yakni CountRange), maka fungsi COUNTIF tersebut juga menghasilkan array, yakni {0;0;0;0;0}. Mengapa 0 (nol) semua? Ini karena nilai "Kota / Kabupaten" tidak terdapat di dalam array {"Boyolali";"Boyolali";"Klaten";"Sleman";"Sleman"}. Yang perlu diperhatikan adalah penulisan range acuannya, yakni $I$2:I2. Terlihat sel awal dibuat absolut (I2) sedangkan sel akhir dibuat relatif. Dengan demikian, ketika kita menyalin formula dari sel I3 ke I4 dan seterusnya, otomatis range acuan tersebut akan 'berkembang'.

    Selanjutnya, array yang dihasilkan oleh fungsi COUNTIF tersebut akan digunakan oleh fungsi MATCH untuk mencari nilai 0 (nol). Mengapa nol? Karena yang dicari adalah nilai pada range CountRange yang belum ada (belum muncul) pada kolom I, yakni mulai dari sel I3.

    = MATCH(0;COUNTIF($I$2:I2;CountRange);0)
    = MATCH(0;{0;0;0;0;0};0)
    = 1

    Dari hasil fungsi COUNTIF di atas, maka fungsi MATCH akan menemukan nilai 0 (nol) pada indeks array yang pertama (ke-1), sehingga hasil dari fungsi MATCH pada sel I3 adalah 1. Selanjutnya, dari fungsi MATCH tersebut kita sudah menemukan indeks baris yang akan diambil dari fungsi INDEX:

    = INDEX(CountRange;MATCH(0;COUNTIF($I$2:I2;CountRange);0))
    = INDEX({"Boyolali";"Boyolali";"Klaten";"Sleman";"Sleman"};1)
    = "Boyolali"

    Sudah mulai paham khan... ?!

  7. Caton

    12 Des 2017 Terverifikasi Indonesia + 12.602 Poin
    Di sunting 11 bulan yang lalu oleh Caton

    Sekarang kita lihat hasil kalkulasi dari formula tersebut pada sel I4.

    = COUNTIF($I$2:I3;CountRange)
    = COUNTIF({"Kota / Kabupaten";"Boyolali"};{"Boyolali";"Boyolali";"Klaten";"Sleman";"Sleman"}) 
    = {1;1;0;0;0}

    Pada formula di atas, oleh karena range $I$2:I3 berisi nilai {"Kota / Kabupaten";"Boyolali"}, maka formulanya dapat dipahami sebagai berikut:

    = COUNTIF({"Kota / Kabupaten";"Boyolali"};"Boyolali") = 1
    = COUNTIF({"Kota / Kabupaten";"Boyolali"};"Boyolali") = 1
    = COUNTIF({"Kota / Kabupaten";"Boyolali"};"Klaten") = 0
    = COUNTIF({"Kota / Kabupaten";"Boyolali"};"Sleman") = 0
    = COUNTIF({"Kota / Kabupaten";"Boyolali"};"Sleman") = 0

    Sehingga terbentuklah hasil akhirnya berupa array {1;1;0;0;0}. Berikutnya bisa ditebak khan? Fungsi MATCH pada formula:

    = MATCH(0;COUNTIF($I$2:I3;CountRange);0)
    = MATCH(0;{1;1;0;0;0};0)
    = 3

    dan fungsi INDEX pada formula:

    = INDEX(CountRange;MATCH(0;COUNTIF($I$2:I3;CountRange);0))
    = INDEX({"Boyolali";"Boyolali";"Klaten";"Sleman";"Sleman"};3)
    = "Klaten"

    akan memberikan hasil berupa nilai "Klaten" pada sel I4. Dan demikian seterusnya. Yang perlu diperhatikan, formulasinya harus dibuat menjadi Array Formula dengan menekan kombinasi tombol CTRL+SHIFT+ENTER (CSE) agar formulanya berfungsi.

    Saya kira demikian yang dapat saya jelaskan, mudah-mudahan tidak menambah pusing mas @Irsyad k tambah pusing. Semoga bermanfaat... ;)

  8. Di sunting 11 bulan yang lalu oleh irsyad k

    terimakasih master @Caton penjelasannya. (panjang banget yak..)

    ni kata-kata menjebak ya master
    "Saya kira demikian yang dapat saya jelaskan, mudah-mudahan tidak menambah pusing mas @Irsyad k tambah pusing. Semoga bermanfaat... ;)"

    tambah pusingbeneran kayaknya ni... :)

  9. Mantap Jiwa Master @Caton

  10. Caton

    14 Des 2017 Terverifikasi Indonesia + 12.602 Poin

    @irsyad k ... ni kata-kata menjebak ya master ...

    Haha... :D Mungkin penjelasan saya yang kedua (tentang formulasi pada sel I4) dapat lebih mudah dipahami. Pelan-pelan saja mas, agar tidak tambah pusing... ;)

    @Nurdin93 Mantap Jiwa Master @Caton

    Terima kasih mas @Nurdin93 ... Saya bukan master, saya juga masih perlu belajar banyak ... ;)

 

atau Mendaftar untuk ikut berdiskusi!